Arduino Power Consumption Normal & Sleep

I often get asked what is the power consumption of an Arduino UNO R3 board:

“Do you have any idea how much current consumption does a Arduino UNO has in no load state (not driving any external output)?”

As I was also curious what the consumption is, I took the time and performed the test, and found out how much current the Arduino UNO R3.

Here’s the video that go over what I did in this test. Take a minute to watch it.

1. Setup the Arduino Uno Board

In my setup I soldered a wire into the fuse down from the USB connector. I ran that wire to my meter. It’s a inexpensive CEN-TECH  Digital Multimeter. The other lead from the meter I connected to my computers USB port, which is 5v. I had a breaker board that help me to do the connections.

2. Measuring Current Draw

And the current is… 46.5mA

Arduino UNO R3 with no load code.

Arduino UNO (at 16mhz, 5v)

3. Calculating the Arduino Power Consumption

Using the formula Power = Voltage x Current

Power = 5v * 46.5mA = 232.5mW

4. Let’s put Arduino put to SLEEP

Let’s take the same Arduino UNO and run the sleep code. The code I have wake up every few seconds upon Watchdog timer timeout and toggle the onboard “L” LED.

Arduino Uno running sleep code. Led is now on

Not bad 46.5mA to 34.4mA is a 26% reduction in current draw. That’s not too bad. Maybe your application can benefit from that reduction and have its battery life extended a bit.

Arduino Uno running sleep code. Led is now off

Notice now with the LED off current came down by 2.2mA. If need to squezze the current draw down, maybe you consider removing those two LEDs.

4. Custom Circuit board (codename OLGA)

Now, let’s compare Arduino Uno with my custom board that I’m working on for a next kickstarter project to be launched by year’s end. Codename for that board is OLGA. Sign up to the mailing list to receive exclusive updates about that upcoming project. This will be a big one!

This board is simply the Arduino chip running at 8MHz 3.3v, as opposed to Arduino UNO’s 5V 16MHz. It turns out there Arduino Pro runs at 8MHz 3.3V, so that may be the easy path for power draw reduction

1456! big number! But notice I change the multimeter scale from mA to uA. So current went from 32mA to 1.4mA! Wow!

Power consumption using sample sleep code in my custom OLGA board. 3.3v 8Mhz. Led on.

But wait. 1456uA was with one LED on – hard to see in the picture. Now with the LED off current is down to 495uA!

Power consumption using sample sleep code in my custom OLGA board. 3.3v 8Mhz. Led off.

5. Result Comparison

Who doesn’t like a nice chart? It’s like the saying goes…  “A chart is worth more than a thousand words”

In conclusion, an Arduino Uno R3 with no load draw 46.5mA and that maybe too high if you’re designing an battery powered application. Using the sleep code does give you a significant improvement. a 26% in battery consumption, but if you want to hit the jackpot you’ll need to take a different route: goto 3.3v and 8Mhz, as you see in my OLGA board. That route can yield to 97% improvement in current draw, which means better battery life.

6. Sleep Code

To get the Arduino sketch that I used in this article, help spread the word about us!

/*
 * Sketch for testing sleep mode with wake up on WDT.
 * Donal Morrissey - 2011.
 *
 */
#include <avr/sleep.h>
#include <avr/power.h>
#include <avr/wdt.h>

#define LED_PIN (13)

volatile int f_wdt=1;

/***************************************************
 *  Name:        ISR(WDT_vect)
 *
 *  Returns:     Nothing.
 *
 *  Parameters:  None.
 *
 *  Description: Watchdog Interrupt Service. This
 *               is executed when watchdog timed out.
 *
 ***************************************************/
ISR(WDT_vect)
{
  if(f_wdt == 0)
  {
    f_wdt=1;
  }
  else
  {
    Serial.println("WDT Overrun!!!");
  }
}

/***************************************************
 *  Name:        enterSleep
 *
 *  Returns:     Nothing.
 *
 *  Parameters:  None.
 *
 *  Description: Enters the arduino into sleep mode.
 *
 ***************************************************/
void enterSleep(void)
{
  set_sleep_mode(SLEEP_MODE_PWR_SAVE);   /* EDIT: could also use SLEEP_MODE_PWR_DOWN for lowest power consumption. */
  sleep_enable();

  /* Now enter sleep mode. */
  sleep_mode();

  /* The program will continue from here after the WDT timeout*/
  sleep_disable(); /* First thing to do is disable sleep. */

  /* Re-enable the peripherals. */
  power_all_enable();
}

/***************************************************
 *  Name:        setup
 *
 *  Returns:     Nothing.
 *
 *  Parameters:  None.
 *
 *  Description: Setup for the serial comms and the
 *                Watch dog timeout. 
 *
 ***************************************************/
void setup()
{
  Serial.begin(9600);
  Serial.println("Initialising...");
  delay(100); //Allow for serial print to complete.

  pinMode(LED_PIN,OUTPUT);

  /*** Setup the WDT ***/

  /* Clear the reset flag. */
  MCUSR &= ~(1<<WDRF);

  /* In order to change WDE or the prescaler, we need to
   * set WDCE (This will allow updates for 4 clock cycles).
   */
  WDTCSR |= (1<<WDCE) | (1<<WDE);

  /* set new watchdog timeout prescaler value */
  WDTCSR = 1<<WDP0 | 1<<WDP3; /* 8.0 seconds */

  /* Enable the WD interrupt (note no reset). */
  WDTCSR |= _BV(WDIE);

  Serial.println("Initialisation complete.");
  delay(100); //Allow for serial print to complete.
}

/***************************************************
 *  Name:        enterSleep
 *
 *  Returns:     Nothing.
 *
 *  Parameters:  None.
 *
 *  Description: Main application loop.
 *
 ***************************************************/
void loop()
{
  if(f_wdt == 1)
  {
    /* Toggle the LED */
    digitalWrite(LED_PIN, !digitalRead(LED_PIN));

    /* Don't forget to clear the flag. */
    f_wdt = 0;

    /* Re-enter sleep mode. */
    enterSleep();
  }
  else
  {
    /* Do nothing. */
  }
}